Générer des suites de valeurs suivant une relation de récurrence

Private Sub CmdGenererValeursSuite_Click()
    ' Procédure événementielle pour générer la suite de termes et rafraîchir le sous-formulaire
    Dim Uo As Double ' variable pour la valeur du terme initial
    Dim FormuleRecurrence As String ' variable pour la formule du terme d'indice n
    Dim n As Long ' variable contenant le nombre de termes de la suite
    Dim Seuil As Double ' variable contenant la valeur du seuil
    Dim IdSuite As Long ' variable contenant l'identifiant de la suite

    If (Nz(Me.txtTermeInitial) <> "") And (Nz(Me.cmbFormuleRecurrence) <> "") And (Nz(Me.txtSeuil) <> "") Then
        ' Si la valeur du terme initial, la formule récurrente et la valeur du seuil ont été saisis
        
        Uo = Me.txtTermeInitial.Value
        FormuleRecurrence = Me.cmbFormuleRecurrence.Value ' on copie la formule de récurrence dans la variable
        Seuil = Me.txtSeuil.Value ' on copie la valeur du seuil saisie sur le formulaire
        IdSuite = Me.[txtIdSuite] ' on copie dans la variable la valeur de l'identifiant de la suite
        If Nz(txtNombreTermes.Value) = "" Then ' si l'utilisateur n'a pas saisi le nombre de termes de la suite
            n = evalNombreTermes(Uo, FormuleRecurrence, Seuil) ' on évalue le nombre de termes de la suite
            txtNombreTermes.Value = n ' on copie le nombre de termes de la suite dans la zone de texte
        Else
            n = txtNombreTermes.Value ' on copie le nombre de termes de la suite dans la variable n
        End If
        GenererSuite Uo, FormuleRecurrence, IdSuite, n - 1 ' on génère la suite de valeurs en fonction des paramètres choisis
        Me.Refresh ' on rafraîchit le formulaire, le sous-formulaire SF_ValeursSuite et le graphique
    Else ' sinon on affiche un message d'alerte
        MsgBox "Choisir une valeur initiale, une formule de récurrence et un seuil pour la suite !", vbExclamation
    End If
End Sub

Public Sub GenererValeursSuite(ByVal Uo As Double, ByVal FormuleRecurrence As String, ByVal IdSuite As Long, n As Long)
    ' Génère la suite des n termes en fonction des paramètres passés en arguments
    
    ' U0 : ' argument pour la valeur du terme initial
    ' FormuleRecurrence : ' argument pour la formule du terme d'indice n
    ' IdSuite : ' argument contenant l'identifiant de la suite
    ' n : ' argument contenant le nombre de termes de la suite
    
    Dim i As Long ' variable d'indice des termes de la suite
    Dim Un As Double ' variable pour la valeur du terme d'indice n
    Dim db As DAO.Database ' référence à la base courante
    Dim rsValeursSuite As DAO.Recordset ' variable objet recordset
        
    Set db = CurrentDb ' référence à la base courante
    
    ' vide les données de la suite dans la table T_ValeursSuite
    db.Execute "delete from T_ValeursSuite where IdSuite=" & IdSuite, dbFailOnError
    
    Set rsValeursSuite = db.OpenRecordset("T_ValeursSuite", dbOpenDynaset) ' ouvre le recordset basé sur la table T_ValeursSuite
    
    Un = Uo  ' on initialise la variable pour les termes de la suite
    
    For i = 0 To n  ' parcours des n+1 termes de la suite
        rsValeursSuite.AddNew ' ajout d'un terme dans la table T_ValeursSuite
        rsValeursSuite!IndiceTerme = i ' copie de l'indice du terme
        rsValeursSuite!ValeurTerme = Un ' copie de la valeur du terme
        rsValeursSuite!IdSuite = IdSuite ' copie de l'identifiant de la suite pour faire le lien avec la tabel T_Suite
        rsValeursSuite.Update
        Un = EvalExpression(FormuleRecurrence, Un, i) ' évaluation de la formule de récurrence pour i+1
    Next i
    
    ' on libère les variables objet
    rsValeursSuite.Close
    Set rsValeursSuite = Nothing
    Set db = Nothing
End Sub

Public Function evalNombreTermes(ByVal Uo As Double, ByVal FormuleRecurrence As String, ByVal Seuil As Double) As Long
    ' Détermine le nombre de termes de la suite
    ' U0 : ' argument pour la valeur du terme initial
    ' FormuleRecurrence : ' argument pour la formule du terme d'indice n
    ' Seuil : ' argument contenant la valeur du seuil
    Dim i As Long, n As Long, Un As Double, s As Integer
    
    Un = Uo ' on initialise le terme de la série
    i = 1 ' on initialise l'indice des termes de la série
    s = Sgn(Seuil - Un) ' signe de la différence entre le seuil et Un
    Do While Sgn(Seuil - Un) = s ' tant qu'on n’a pas atteint le seuil
        s = Sgn(Seuil - Un) ' signe de la différence entre le seuil et Un
        Un = EvalExpression(FormuleRecurrence, Un, i) ' évaluation de la formule de récurrence pour n=i
        i = i + 1 ' on incrémente l'indice des termes de la série
        If i > 2000 Then Exit Do ' on définit une limite pour sortir avant que le seuil soit atteint
    Loop
    evalNombreTermes = i ' on renvoie l'indice du dernier terme dont la valeur est supérieure ou égale au seuil
End Function

Debug.Print Eval("2+3")
renvoie 5
Debug.Print Eval("2*3")
renvoie 6
...

Private Function EvalExpression(ByVal FormuleRecurrence As String, ByVal Un As Double, ByVal n As Long) As Double
    ' Evalue l'expression obtenue à partir de la formule de récurrence
    ' FormuleRecurrence : ' argument pour la formule du terme d'indice n
    ' Un : ' argument pour la valeur du terme d'indice n
    ' n : ' argument contenant l'indice n de la suite
    ' la formule est du type : n*Un + 10, il faut identifier Un dans cette formule
    FormuleRecurrence = Replace(FormuleRecurrence, "Un", Replace(CStr(Un), ",", "."))
    FormuleRecurrence = Replace(FormuleRecurrence, "n", CStr(n)) ' puis, on identifie n dans la formule
    EvalExpression = Eval(FormuleRecurrence) ' enfin, on évalue l'expression obtenue
End Function

Public Function BarreProgression(valeur As Double, valeurMax As Double, maximum As Long) As String
    ' valeur : argument indiquant la valeur de la suite pour un certain indice
    ' valeurMax : argument indiquant la valeur maxi de la suite
    ' maximul : argument indiquant la valeur maxi de la barre de progression
    Dim pp As Double, pg As Long, pr As Long
    
    pp = valeur / valeurMax ' proportion par rapport au total
    pg = CInt(pp * maximum) ' progression par rapport à la valeur maxi de la barre
    
    pr = (maximum - pg) ' progression restante
    
    If pg < 0 Then ' si la progression pg est négative
        pg = 0 ' on met 0 pour la progression
        pr = maximum
    End If
    If pr < 0 Then ' si la progression pg est supérieure à la valeur maxi
        pr = 0 ' on a 0 pour le reste de la progression
    End If
    ' On renvoie la progression de la suite sous la forme d'une barre de progression composée d'une chaîne de caractères
    BarreProgression = String(pg, ChrW(&H2588)) & String(pr, ChrW(&H2591)) & " " & Format(pp, "0.00 %")
End Function